תחביר ופונקציות של נוסחאות

כותרת

prop("Title")prop("Title").length()

טקסט

טקסט

prop("Text")prop("Text").length()

טקסט

בחירה

prop("Priority") == "High"

טקסט

בחירה מרובה

prop("Tags").length()prop("Tags").includes("Finance")

טקסט (רשימה)

תיבת סימון

prop("Checkbox")
not prop("Checkbox")

בוליאנית

אימייל, כתובת URL, מספר טלפון

!empty(prop("Phone"))
!empty(prop("Email"))
link("Call", "tel:" + prop("Phone"))

טקסט

מזהה ייחודי

prop("Task ID").split("-").first() ← Prefix
prop("Task ID").split("-").last() ← ID

טקסט

נוצר על ידי,
נערך על ידי

prop("Created By").name()
prop("Created By").email()

אדם

אדם

prop("Person")
prop("Person").at(0).name()
prop("Person").map(current.email())

אדם (רשימה)

תאריך,
זמן יצירה,
זמן עריכה אחרון

prop("Due Date") > now()
dateBetween(prop("Birthday"), now(), "days")

תאריך

מספר

prop("Number") / 2
pi() * prop("Radius") ^ 2

מספר

יחס

prop("Tasks").length()
prop("Tasks").filter(current.prop("Status") !== "Done")

דף (רשימה)

רול-אפ

prop("Purchases").length()
prop("Average cost") * 12

מספר, תאריך או רשימה מכל סוג שהוא. תלוי בתצורת הרול-אפ.

מפעילי מתמטיקה:+, -, *, %

2 * pi()"hello" + "world"

ערכים בוליאניים:
true, false

truefalse

מפעילי השוואה:
==, >, >=, <, <=

123 == 123 = true"Notion" == "Motion" = false

מפעילים לוגיים:
ו, או, לא

and:true and false
true && falseand(true, false)
or:true or false
true || falseor(true, false)
not:not true
!true

אופרטור טרנארי:
? :

X ? Y : Z שווה ערך ל- if(X, Y, Z)

מספקת את הערך הראשון אם התנאי הוא 'true'; במידה ולא, היא מספקת את הערך השני.

if(true, 1, 2) = 1if(false, 1, 2) = 2prop("Checked") == true ? "Complete" : "Incomplete"

מחזירה את הערך המתאים לתנאי האמת הראשון. ניתן להשתמש בפונקציה זו כחלופה להצהרות משנה מרובות של if().

ifs(true, 1, true, 2, 3) = 1ifs(false, 1, false, 2, 3) = 3

מחזירה 'true' אם הערך ריק. 0, "" ו-[] נחשבים ריקים.

empty(0) = trueempty([]) = true

מספקת את אורך הטקסט או את ערך הרשימה.

length("hello") = 5length([1, 2, 3]) = 3

מספקת את תת-מחרוזת הטקסט מאינדקס ההתחלה (כולל) לאינדקס הסיום (אופציונלי ואקסלוסיבי).

substring("Notion", 0, 3) = "Not"substring("Notion", 3) = "ion"

מספקת 'true' אם מחרוזת החיפוש קיימת בערך.

contains("Notion", "ot") = true

מספקת 'true' אם הערך תואם לביטוי הרגיל, ואם לא – 'false'.

test("Notion", "Not") = truetest("Notion", "\\d") = false

מספקת את כל ההתאמות של הביטוי הרגיל כרשימה.

match("Notion Notion", "Not") = ["Not", "Not"]match("Notion 123 Notion 456", "\\d+") = ["123", "456"]

מחליפה את ההתאמה הראשונה של הביטוי הרגיל בערך החלופי.

replace("Notion Notion", "N", "M") = "Motion Notion"

מחליפה את כל ההתאמות של הביטוי הרגיל בערך החלופי.

replaceAll("Notion Notion", "N", "M") = "Motion Motion"replaceAll("Notion 123", "\\d", "") = "Notion"

ממירה את הטקסט לאותיות קטנות.

lower("NOTION") = "notion"

ממירה את הטקסט לאותיות גדולות.

upper("notion") = "NOTION"

חוזרת על הטקסט מספר פעמים נתון.

repeat("0", 4) = "0000"repeat("~=", 10) = "~=~=~=~=~=~=~=~=~=~="

יוצרת היפר-קישור מטקסט התווית ומכתובת ה-URL.

link("Notion", "https://notion.so") = "Notion"

מוסיפה סגנונות וצבעים לטקסט. סגנונות עיצוב חוקיים: "b" (מודגש), "u" (קו תחתון), "i" (נטוי), "c" (קוד) או "s" (קו חוצה). צבעים חוקיים: "gray", "brown", "orange", "yellow", "green", "blue", "purple", "pink", and "red". יש להוסיף "_background" לצבעים כדי להגדיר צבעי רקע.

style("Notion", "b", "u") = "Notion" style("Notion", "blue", "gray_background")

מסירה סגנונות עיצוב מהטקסט. אם לא צוינו סגנונות, כל הסגנונות יוסרו.

unstyle("Text")unstyle("Text", "b")

מספקת את הערך בפורמט טקסט.

format(1234) = "1234"format(now()) = "August 30, 2023 17:55"

מספקת את הסכום של שני מספרים.

add(5, 10) = 155 + 10 = 15

מחזירה את ההפרש בין שני מספרים.

subtract(5, 10) = -55 - 10 = -5

מספקת את המכפלה של שני מספרים.

multiply(5, 10) = 505 * 10 = 50

מספקת את שארית החלוקה של המספר הראשון מהמספר השני.

mod(5, 10) = 55 % 10 = 5

מספקת את התוצאה של מספר בסיס שהועלה בחזקה.

pow(5, 10) = 97656255 ^ 10 = 9765625

מספקת את המנה של שני מספרים.

divide(5, 10) = 0.55 / 10 = 0.5

מספקת את המספר הקטן ביותר של הארגומנטים.

min(1, 2, 3) = 1min([1, 2, 3]) = 1

מספקת את המספר הגדול ביותר של הארגומנטים.

max(1, 2, 3) = 3max([1, 2, 3]) = 3

מספקת את הסכום של הארגומנטים.

sum(1, 2, 3) = 6sum([1, 2, 3], 4, 5) = 15

median

מספקת את הערך האמצעי של הארגומנטים שלה.

median(1, 2, 4) = 2
median([1, 2, 3], 4) = 2.5

mean

מספקת את הממוצע האריתמטי של הארגומנטים.

mean(1, 2, 3) = 2
mean([1, 2, 3], 4, 5) = 3

מספקת את הערך המוחלט של המספר.

abs(10) = 10abs(-10) = 10

מספקת את הערך של מספר מעוגל למספר השלם הקרוב ביותר. תומכת בארגומנט אחד או שניים. במקרה של שני ארגומנטים, הראשון מייצג את הערך והשני מייצג את מספר המקומות העשרוניים שאליהם יש לעגל.

round(0.4) = 0round(-0.6) = -1
round(1.234, 0) = 1round(1.234, 2) = 1.23round(1234, -2) = 1200

מספקת את המספר השלם הקטן ביותר שגדול או שווה למספר.

ceil(0.4) = 1ceil(-0.6) = 0

מספקת את המספר השלם הגדול ביותר שהוא פחות מהמספר או שווה לו.

floor(0.4) = 0floor(-0.6) = -1

מספקת את השורש הריבועי החיובי של המספר.

sqrt(4) = 2sqrt(7) = 2.6457513110645907

מספקת את השורש השלישי של המספר.

cbrt(9) = 2.080083823051904cbrt(64) = 4

מספקת e^x, כאשר x הוא הפרמטר, ו-e הוא מספר אוילר (2.718...), הבסיס של הלוגריתם הטבעי.

exp(1) = 2.718281828459045exp(-1) = 0.36787944117144233

מספקת את הלוגריתם הטבעי של המספר.

ln(2.718281828459045) = 1ln(10) = 2.302585092994046

מספקת את הלוגריתם של בסיס 10 של המספר.

log10(10) = 1log10(100000) = 5

מספקת את הלוגריתם של בסיס 2 של המספר.

log2(4) = 2log2(1024) = 10

מספקת 1 אם המספר חיובי, -1 אם הוא שלילי ו-0 אם הוא אפס.

sign(-10) = -1sign(10) = 1

מחזירה את היחס בין היקף מעגל לקוטר שלו.

pi() = 3.141592653589793

מחזירה את בסיס הלוגריתם הטבעי.

e() = 2.718281828459045

מנתחת מספר מטקסט.

toNumber("2") = 2toNumber(now()) = 1693443300000toNumber(true) = 1

מספקת את התאריך והשעה הנוכחיים.

now() = @August 30, 2023 5:55 PM

היום

מספקת את התאריך הנוכחי ללא השעה.

today() = @April 19, 2024

מספקת את הדקה של התאריך (0-59).

minute(parseDate("2023-07-10T17:35Z")) = 35

מספקת את השעה של התאריך (0-23).

hour(parseDate("2023-07-10T17:35Z")) = 17

מספקת את היום בשבוע של התאריך, בין 1 (יום שני) ל-7 (יום ראשון).

day(parseDate("2023-07-10T17:35Z")) = 1

מספקת את היום בחודש מהתאריך (1-31).

date(parseDate("2023-07-10T17:35Z")) = 10

מספקת את שבוע ה-ISO של שנת התאריך (1-53).

week(parseDate("2023-01-02")) = 1

מספקת את החודש של התאריך (1-12).

month(parseDate("2023-07-10T17:35Z")) = 7

מספקת את שנת התאריך.

year(now()) = 2023

מוסיפה זמן לתאריך. הארגומנט של היחידה יכול להיות אחד מהבאים:"years", "quarters", "months", "weeks", "days", "hours", or "minutes".

dateAdd(now(), 1, "days") = @August 31, 2023 5:55 PMdateAdd(now(), 2, "months") = @October 30, 2023 5:55
PMdateAdd(now(), 3, "years") = @August 30, 2026 5:55 PM

מחסירה זמן מהתאריך. הארגומנט של היחידה יכול להיות אחד מהבאים:"years", "quarters", "months", "weeks", "days", "hours", or "minutes".

dateSubtract(now(), 1, "days") = @August 29, 2023 5:55 PMdateSubtract(now(), 2, "months") = @June 30, 2023 5:55 PMdateSubtract(now(), 3, "years") = @August 30, 2020 5:55 PM

מחזירה את ההפרש בין שני תאריכים. הארגומנט של היחידה יכול להיות אחד מהבאים:"years", "quarters", "months", "weeks", "days", "hours", or "minutes".

dateBetween(now(), parseDate("2022-09-07"), "days") = 357dateBetween(parseDate("2030-01-01"), now(), "years") = 6

מספקת טווח תאריכים שנבנה מתאריכי ההתחלה והסיום.

dateRange(prop("Start Date"), prop("End Date")) = @September 7, 2022 → September 7, 2023

מספקת את תחילת טווח התאריכים.

dateStart(prop("Date Range")) = @September 7, 2022dateBetween(dateStart(prop("Date Range")), dateEnd(prop("Date Range")), "days") = -365

מספקת את סוף טווח התאריכים.

dateEnd(prop("Date range")) = @September 7, 2023dateBetween(dateEnd(prop("Date Range")), dateStart(prop("Date Range")), "days") = 365

מספקת את חותמת הזמן הנוכחית של Unix, המייצגת את מספר המילישניות שחלפו מאז 1 בינואר 1970.

timestamp(now()) = 1693443300000

מחזירה את התאריך מחותמת הזמן הנתונה של Unix. חותמת הזמן מייצגת את מספר המילישניות שחלפו מאז 1 בינואר 1970. הערה: התאריך המוחזר לא ישמור את השניות והמילישניות.

fromTimestamp(1689024900000) = @July 10, 2023 2:35 PM

מעצבת את התאריך באמצעות מחרוזת פורמט מותאמת אישית. מחרוזת הפורמט יכולה להכיל את הטקסט הבא כדי לייצג חלקים מהתאריך: "YYYY" לשנה, "MM" לחודש, "DD" ליום, "h" לשעה, "mm" לדקה.

formatDate(now(), "MMMM D, Y") = "August 30, 2023"
formatDate(now(), "MM/DD/YYYY") = "08/30/2023"
formatDate(now(), "h:mm A") = "17:55 PM"

מספקת את התאריך בפורמט ISO 8601.

parseDate("2022-01-01") = @January 1, 2022parseDate("2022-01-01T00:00Z") = @December 31, 2021 4:00 PM

מספקת את שם האדם.

name(prop("Created By"))prop("Pioneers").map(name(current)).join(", ") = "Grace Hopper, Ada Lovelace"

מספקת את כתובת האימייל של אדם.

email(prop("Created By"))prop("People").map(email(current)).join(", ")

מספקת את הערך באינדקס שצוין ברשימה.

at([1, 2, 3], 1) = 2

מספקת את הפריט הראשון ברשימה.

first([1, 2, 3]) = 1

מספקת את הפריט האחרון ברשימה.

last([1, 2, 3]) = 3

מספקת את הפריטים של הרשימה מאינדקס ההתחלה שסופק (כולל) לאינדקס הסיום (אופציונלי ואקסלוסיבי).

slice([1, 2, 3], 1, 2) = [2]slice(["a", "b", "c"], 1) = ["b", "c"]

מספקת את הרצף של מספר רשימות.

concat([1, 2], [3, 4]) = [1, 2, 3, 4]concat(["a", "b"], ["c", "d"]) = ["a", "b", "c", "d"]

מחזירה את הרשימה בסדר ממוין.

sort([3, 1, 2]) = [1, 2, 3]

מספקת את הרשימה בסדר הפוך.

reverse(["green", "eggs", "ham"]) = ["ham", "eggs", "green"]

מספקת את הערכים של הרשימה כאשר המחבר ממוקם בין כל אחד מהערכים.

join(["a", "b", "c"], ", ") = "a, b, c"join(["dog", "go"], "") = "doggo"

מספקת את רשימת הערכים שנוצרו על ידי פיצול קלט טקסט באמצעות מפריד.

split("apple,pear,orange", ",") = ["apple", "pear", "orange"]

מספקת את רשימת הערכים הייחודיים ברשימת הקלט.

unique([1, 1, 2]) = [1, 2]

מספקת 'true' אם הרשימה מכילה את הערך שצוין, ואם לא – 'false'.

includes(["a", "b", "c"], "b") = trueincludes([1, 2, 3], 4) = false

מספקת את הפריט הראשון ברשימה שעבורו התנאי הוא 'true'.

find(["a", "b", "c"], current == "b") = "b"find([1, 2, 3], current > 100) = Empty

מספקת את האינדקס של הפריט הראשון ברשימה שעבורו התנאי הוא 'true'.

findIndex(["a", "b", "c"], current == "b") = 1findIndex([1, 2, 3], current > 100) = -1

מספקת את הערכים ברשימה שעבורם התנאי הוא 'true'.

filter([1, 2, 3], current > 1) = [2, 3]filter(["a", "b", "c"], current == "a") = ["a"]

מספקת 'true' אם פריט כלשהו ברשימה עומד בתנאי הנתון, ואם לא – 'false'.

some([1, 2, 3], current == 2) = truesome(["a", "b", "c"], current.length > 2) = false

מספקת 'true' אם כל פריט ברשימה עומד בתנאי הנתון, ואם לא – 'false'.

every([1, 2, 3], current > 0) = trueevery(["a", "b", "c"], current == "b") = false

מספקת את הרשימה מלאה בתוצאות של קריאת הביטוי בכל פריט ברשימת הקלט.

map([1, 2, 3], current + 1) = [2, 3, 4]map([1, 2, 3], current + index) = [1, 3, 5]

משטחת רשימה של רשימות לרשימה אחת.

flat([1, 2, 3]) = [1, 2, 3]flat([[1, 2], [3, 4]]) = [1, 2, 3, 4]

מחזירה את המזהה של הדף. אם לא סופק דף, היא מחזירה את המזהה של הדף שבו נמצאת הנוסחה.

id()
id(prop("Relation").first())

מספקת 'true' אם שני הערכים שווים, ואם לא – 'false'.

equal(1, 1) = true"a" == "b" = false

מחזירה 'false' אם שני הערכים שווים, ואם לא – 'true'.

unequal(1, 2) = true"a" != "a" = false

מקצה ערך למשתנה ומעריכה את הביטוי באמצעות משתנה זה.

let(person, "Alan", "Hello, " + person + "!") = "Hello, Alan!"let(radius, 4, round(pi() * radius ^ 2)) = 50

מקצה ערכים למשתנים מרובים ומעריכה את הביטוי באמצעות משתנים אלה.

lets(a, "Hello", b, "world", a + " " + b) = "Hello world"lets(base, 3, height, 8, base * height / 2) = 12

trim

מסירה רווחים מתחילת וסוף הטקסט.

" notion ".trim() = "notion"